/*
 * Copyright (c) 2009, Mason Green (zzzzrrr)
 * http://www.dsource.org/projects/openmelee
 * 
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without modification,
 * are permitted provided that the following conditions are met:
 *
 * * Redistributions of source code must retain the above copyright notice,
 *   this list of conditions and the following disclaimer.
 * * Redistributions in binary form must reproduce the above copyright notice,
 *   this list of conditions and the following disclaimer in the documentation
 *   and/or other materials provided with the distribution.
 * * Neither the name of the polygonal nor the names of its contributors may be
 *   used to endorse or promote products derived from this software without specific
 *   prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
 * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
 * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
 * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
 * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
 * NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */
module openmelee.ships.ship;

import tango.io.Stdout: Stdout;
import tango.math.Math : PI;

import tango.util.container.LinkedList : LinkedList;
import blaze.dynamics.bzBody : bzBody;
import blaze.collision.shapes.bzShape : bzShape, bzShapeDef, bzMassData;
import blaze.collision.shapes.bzShapeType;
import blaze.common.bzMath: bzVec2, bzCross, bzClamp;
import blaze.bzWorld : bzWorld;
import blaze.dynamics.forces.bzAttractor: bzAttractor;
import blaze.dynamics.bzBodyDef : bzBodyDef;
import blaze.collision.shapes.bzPolygon : bzPolyDef, bzPolygon;
import blaze.collision.shapes.bzCircle : bzCircleDef;

import openmelee.ai.utilities : randomRange;
//import openmelee.test.wrap;

alias LinkedList!(bzShape) ShapeList;

struct State 
{
	bzVec2 position;
    bzVec2 velocity;
    bzVec2 up;
    bzVec2 side;
    bzVec2 forward;
    bzVec2 target;
	float speed = 0;
	float maxForce = 0;
	bool turn;
    float radius = 0.0f;
	float enemyAngle = 0.0f;
    bzVec2 avoid;
	
    Ship enemy;
    
	bzVec2 predictFuturePosition(float dt) {
	    return (position + velocity * dt);
    }
}

abstract class Ship
{
    bzWorld world;
    bzBody rBody;
    ShapeList shapes;
    bzVec2 engineForce;
    bzVec2 turnForce;
    bzVec2 leftTurnPoint;
    bzVec2 rightTurnPoint;
	State state;
	
    float battery = 0.0f;
    float crew = 0.0f;
    
    float maxLinVel = 50;
    float maxAngVel = 2;
    
    this(bzWorld world) {
        this.world = world;
        shapes = new ShapeList;
    }

    void thrust() {
        rBody.force += engineForce.rotate(rBody.angle);
    }

    void turnLeft() {
        
        rBody.torque += bzCross(leftTurnPoint.rotate(rBody.angle), 
                                turnForce.rotate(rBody.angle));
    }
    
    void turnRight() {
        
        rBody.torque += bzCross(rightTurnPoint.rotate(rBody.angle), 
                                turnForce.rotate(rBody.angle));
    }
    
    void setPlanetGravity() {
        float minRadius = 0.1;
        float maxRadius = 10;
        float strength = 2.5;
        bzVec2 center = bzVec2(0,0);
        auto attractor = new bzAttractor(rBody, center, strength, minRadius, maxRadius);
        world.addForce(attractor);
    }
    
    void limitVelocity() {
        float vx = rBody.linearVelocity.x;
        float vy = rBody.linearVelocity.y;
        float av = rBody.angularVelocity;
        rBody.linearVelocity.x = bzClamp(vx, -maxLinVel, maxLinVel);
        rBody.linearVelocity.y = bzClamp(vy, -maxLinVel, maxLinVel);
        rBody.angularVelocity = bzClamp(av, -maxAngVel, maxAngVel);
    }
    
    void updateState() {
    	state.velocity = rBody.linearVelocity;
    	state.speed = state.velocity.length;
    	state.position = rBody.position;
    	state.forward = engineForce.rotate(rBody.angle);
    }
    
    void calcRadius() {
        for (bzShape s = rBody.shapeList; s; s = s.next) {
            if(s.sweepRadius > state.radius) {
                state.radius = s.sweepRadius;
            }
        }
    }
    
    void explode() {
        for(bzShape shape = rBody.shapeList; shape; shape = shape.next) {
            auto bodyDef = new bzBodyDef;
            switch(shape.type) {
                case bzShapeType.POLYGON:
                    auto s = cast(bzPolygon) shape;
                    auto shapeDef = new bzPolyDef;
                    shapeDef.vertices = s.vertices;
                    shapeDef.density = s.density;
                    bodyDef.position = s.worldCenter;
                    bodyDef.angle = randomRange(-PI, PI);
                    bodyDef.allowFreeze = false;
                    bodyDef.allowSleep = false;
                    auto shrapnel = world.createBody(bodyDef);             
                    shrapnel.createShape(shapeDef);
                    bzMassData massData;
                    massData.mass = 5.0f;
                    shrapnel.setMass(massData);
                    float x = randomRange(-300, 300);
                    float y = randomRange(-300, 300);
                    shrapnel.linearVelocity = bzVec2(x, y);
                    break;
                default:
                    break;
            }
        }
    }
            
}