/* LICENSE BLOCK
Part of mde: a Modular D game-oriented Engine
Copyright © 2007-2008 Diggory Hardy

This program is free software: you can redistribute it and/or modify it under the terms
of the GNU General Public License as published by the Free Software Foundation, either
version 2 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>. */

/*************************************************************************************************
 * A function to return content widgets and some miscellaneous content widgets.
 *************************************************************************************************/
module mde.gui.widget.miscContent;

import mde.gui.widget.Widget;
import mde.gui.exception;
import mde.gui.widget.textContent;
import mde.gui.widget.layout;

import mde.gui.renderer.IRenderer;
import mde.content.AStringContent;
import Items = mde.content.Items;

debug {
    import tango.util.log.Log : Log, Logger;
    private Logger logger;
    static this () {
	logger = Log.getLogger ("mde.gui.widget.miscContent");
    }
}

/*************************************************************************************************
 * A function which uses Items.get (data.strings[0]) to get a content and creates a widget from
 * data.ints[1]. The first item in each ints and strings is removed before passing data to the new
 * widget.
 * 
 * The function only takes an IContent parameter to satisfy createWidget; it's value is ignored.
 *************************************************************************************************/
IChildWidget addContent (IWidgetManager mgr, widgetID id, WidgetData data, IContent) {
    if (data.ints.length < 2 || data.strings.length < 1) throw new WidgetDataException;
    char[] cItem = data.strings[0];
    data.strings = data.strings[1..$];
    data.ints    = data.ints   [1..$];
    return mgr.makeWidget (id, data, Items.get (cItem));
}

/*************************************************************************************************
 * A function which returns the most appropriate content editing widget.
 *
 * Widgets which can be returned: BoolContentWidget (toggle button), ValueContentWidget (generic
 * text-box editor), DisplayContentWidget (generic text label).
 *************************************************************************************************/
IChildWidget editContent (IWidgetManager mgr, widgetID id, WidgetData data, IContent c) {
    if (c is null) throw new ContentException;
    if (cast(BoolContent) c)
        return new BoolContentWidget(mgr,id,data,c);
    else if (cast(AStringContent) c) {
	if (cast(EnumContent) c)
	    return new EnumContentWidget(mgr,id,data,c);
	else
	    return new AStringContentWidget(mgr,id,data,c);
    } else if (cast(ContentList) c)
	return new ContentListWidget(mgr,id,data,c);
    else if (cast(EventContent) c)
	return new ButtonContentWidget(mgr,id,data,c);
    else	// generic uneditable option
        return new DisplayContentWidget(mgr,id,data,c);
}

/// Editable boolean widget
class BoolContentWidget : AButtonWidget
{
    this (IWidgetManager mgr, widgetID id, WidgetData data, IContent c) {
	content = cast(BoolContent) c;
	WDCCheck(data, 1,0, content);
        wdimPair s = mgr.renderer.getToggleSize;
        w = mw = s.x;
        h = mh = s.y;
        super (mgr, id, data);
    }
    
    void draw () {
        mgr.renderer.drawToggle (x,y, content(), pushed);
    }
    
    void activated () {
        content = !content();
    }
    
protected:
    BoolContent content;
}

/// A button connected to an EventContent
class ButtonContentWidget : AButtonWidget
{
    this (IWidgetManager mgr, widgetID id, WidgetData data, IContent c) {
	content = cast(EventContent) c;
	WDCCheck (data, 1,0, content);
	adapter = mgr.renderer.getAdapter ();
	super (mgr, id, data);
    }
    
    bool setup (uint n, uint flags) {
	if (!(flags & 3)) return false;	// string or renderer (and possibly font) changed
	adapter.text = content.toString(1);
	adapter.getDimensions (mw, mh);
	if (mw != w || mh != h) {
	    w = mw;
	    h = mh;
	}
	return true;
    }
    
    void draw () {
	super.draw();
	adapter.draw (x,y);
    }
    
    void activated () {
	content.endEvent;
    }
    
    protected:
	IRenderer.TextAdapter adapter;
	EventContent content;
	int index;
}
/// Pops up a list of selectable values
class EnumContentWidget : AButtonWidget
{
    this (IWidgetManager mgr, widgetID id, WidgetData data, IContent c) {
	content = cast(EnumContent) c;
	WDCCheck (data, 1,0, content);
	adapter = mgr.renderer.getAdapter;
	adapter.text = content.toString (0);
	adapter.getDimensions (mw, mh);
	w = mw;
	h = mh;
	internalWidg = new EnumContentPopup (mgr, id, data, content);
	super (mgr, id, data);
    }
    
    void changeContent () {
	adapter.text = content.toString (0);
	adapter.getDimensions (mw, mh);
	w = mw;
	h = mh;
    }
    
    void activated () {
	mgr.addPopup (this, internalWidg);
    }
    
    void draw () {
	super.draw;
	adapter.draw (x,y);
    }
    
protected:
    EnumContentPopup internalWidg;	// setup & saveChanges calls not propegated
    EnumContent content;
    IRenderer.TextAdapter adapter;
    
    /// The widget which gets popped up
    class EnumContentPopup : AButtonWidget
    {
	/// Assumes EnumContent c isn't null
	this (IWidgetManager mgr, widgetID id, WidgetData data, EnumContent c) {
	    content = c;
	    adapters.length = content.enumSymbols.length;
	    yPos.length = adapters.length;
	    // mh is 0
	    foreach (i, ref adapter; adapters) {
		adapter = mgr.renderer.getAdapter;
		adapter.text = content.toString(i+3);
		wdim aw, ah;
		adapter.getDimensions (aw,ah);
		if (mw < aw) mw = aw;
		yPos[i] = mh;
		mh += ah;
	    }
	    w = mw;
	    h = mh;
	    super (mgr, id, data);
	}
	
	void draw () {
	    super.draw;
	    foreach (i,yp; yPos) {
		adapters[i].draw (x,y+yp);
	    }
	}
	
	/// Called when a mouse click event occurs while held; handles up-click
	bool clickWhilePushed (wdabs cx, wdabs cy, ubyte b, bool state) {
	    if (b == 1 && state == false) {
		cy -= y;
		if (cx >= x && cx < x+w && cy >= 0 && cy < h) {
		    uint i = yPos.length-1;
		    for (; i > 0; --i)
			if (cy >= yPos[i])
			    break;
		    logger.trace ("Setting value: {}", i);
		    content = i;
		    //mgr.removePopup (this);
		    changeContent;
		}
		
		pushed = false;
		mgr.requestRedraw;
		mgr.removeCallbacks (cast(void*) this);
		
		return true;
	    }
	    return false;
	}
	
	void activated () {}
	
    protected:
	EnumContent content;
	IRenderer.TextAdapter[] adapters;	// NOTE: replace with multi-line adapter
	wdrel[] yPos;	// y position of each adapter
    }
}