/* LICENSE BLOCK
Part of mde: a Modular D game-oriented Engine
Copyright © 2007-2008 Diggory Hardy

This program is free software: you can redistribute it and/or modify it under the terms
of the GNU General Public License as published by the Free Software Foundation, either
version 2 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>. */

/** The content system − common interface and a few classes without external dependencies.
 */
module mde.content.Content;

import util = mde.util;

debug {
    import tango.util.log.Log : Log, Logger;
    private Logger logger;
    static this () {
        logger = Log.getLogger ("mde.content.Content");
    }
}

/** IContent − interface for all Content classes.
 *
 * Services like copy/paste could work on universal content. However, they would need to run a
 * conversion to the appropriate type (or try next-oldest item on clipboard?). */
interface IContent
{
    /** Generically return strings.
     *
     * This serves two purposes: generically returning a string of/related to the content (i == 0),
     * and returning associated descriptors. Functions should adhere to (or add to) this table.
     *
     *  $(TABLE
     *  $(TR $(TH i) $(TH returns))
     *  $(TR $(TD 0) $(TD value))
     *  $(TR $(TD 1) $(TD Translated name or null))
     *  $(TR $(TD 2) $(TD Translated description or null))
     *  $(TR $(TD other) $(TD null))
     *  ) */
    char[] toString (uint i);
}

/** The base for $(I most) content classes.
 *
 * Includes generic callback support, toString implementation and symbol access.
 * 
 * Derived classes should impement:
 * ---
 *  this (char[] symbol, T val = /+ default value +/);
 *  void opAssign (T val);	// assign val, calling callbacks
 *  T opCall ();		// return value
 *  alias opCall opCast;
 * --- */
class AContent : IContent
{
    this (char[] symbol) {
	this.symbol = symbol;
    }
    
    void name (char[] n, char[] d = null) {
	name_ = n;
	desc_ = d;
    }
    
    /** Add a callback. Callbacks are called in the order added. */
    EventContent addCallback (void delegate (AContent) cb) {
	this.cb ~= cb;
	return this;
    }
    /// ditto
    EventContent addCallback (void function (AContent) cb) {
	this.cb ~= util.toDg (cb);
	return this;
    }
    
    char[] toString (uint i) {
	return i == 0 ? "No value"
	: i == 1 ? name_
	: i == 2 ? desc_
	: null;
    }
    
    /// End of an event, e.g. a button release or end of an edit (calls callbacks).
    void endEvent () {
	foreach (dg; cb)
	    dg (this);
    }
    
    final char[] symbol;	// Symbol name for this content
protected:
    char[] name_, desc_;	// name and description
    void delegate (AContent) cb[];
}

/** A generic way to handle a list of type IContent. */
class ContentList : AContent
{
    this (char[] symbol, AContent[] list = null) {
	list_.length = list.length;
	foreach (i,c; list)
	    list_[i] = c;
	super (symbol);
    }
    this (char[] symbol, AContent[char[]] l) {
	list_.length = l.length;
	size_t i;
	foreach (c; l)
	    list_[i++] = c;
	super (symbol);
    }
    
    IContent[] list () {
	return list_;
    }
    
protected:
    final IContent[] list_;
}

/** Created on errors to display and log a message. */
class ErrorContent : IContent
{
    this (char[] msg) {
	msg_ = msg;
    }
    
    char[] toString (uint i) {
	return i == 0 ? msg_
	     : i == 1 ? "Error"
	     : null;
    }
    
protected:
    char[] msg_;
}

/** A Content with no value but able to pass on an event.
*
* The point being that a button can be tied to one of these. */
alias AContent EventContent;