/* LICENSE BLOCK
Part of mde: a Modular D game-oriented Engine
Copyright © 2007-2008 Diggory Hardy

This program is free software: you can redistribute it and/or modify it under the terms
of the GNU General Public License as published by the Free Software Foundation, either
version 2 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>. */

/** Some GUI Miscelaneas widgets. */
module mde.gui.widget.miscWidgets;

import mde.gui.widget.Widget;
import mde.gui.exception;
import mde.gui.renderer.IRenderer;

import tango.io.Stdout;


/// A fixed-size blank widget.
class FixedBlankWidget : FixedWidget
{
    this (IWidgetManager mgr, widgetID id, WidgetData data) {
        WDCheck (data, 3);
        super (mgr, id, data);
    }
    
    void draw () {
        super.draw;
        
        mgr.renderer.drawBlank (x,y, w,h);
    }
}

/// A completely resizable blank widget (initial size zero).
class SizableBlankWidget : SizableWidget
{
    this (IWidgetManager mgr, widgetID id, WidgetData data) {
        WDCheck (data, 1);
        super (mgr, id, data);
    }
    
    void draw () {
        super.draw;
        
        mgr.renderer.drawBlank (x,y, w,h);
    }
}

/// A debug widget. Essentially as SizableBlankWidget but doesn't mind any amount of data and prints it.
class DebugWidget : SizableWidget
{
    this (IWidgetManager mgr, widgetID id, WidgetData data) {
        super (mgr, id, data);
        
        Stdout ("Debug widget - parameters: int: [");
        foreach (x; data.ints)
            Stdout (" ")(x);
        Stdout (" ], char[]: [");
        foreach (x; data.strings)
            Stdout (" \"")(x)('"');
        Stdout (" ]").newline;
    }
    
    void draw () {
        super.draw;
        
        mgr.renderer.drawBlank (x,y, w,h);
    }
}

/// First interactible widget
class ButtonWidget : FixedWidget
{
    bool pushed = false;    // true if button is pushed in (visually)
    // pushed is not the same as the button being clicked but not yet released.
    // it is whether the mouse is over the button after being clicked.
    
    this (IWidgetManager mgr, widgetID id, WidgetData data) {
        WDCheck (data, 3);
        super (mgr, id, data);
    }
    
    void draw () {
        mgr.renderer.drawButton (x,y, w,h, pushed);
    }
    
    void clickEvent (wdabs, wdabs, ubyte b, bool state) {
        if (b == 1 && state == true) {
            pushed = true;
            mgr.requestRedraw;
            mgr.addClickCallback (&clickWhileHeld);
            mgr.addMotionCallback (&motionWhileHeld);
        }
    }
    // Called when a mouse motion/click event occurs while (held == true)
    bool clickWhileHeld (wdabs cx, wdabs cy, ubyte b, bool state) {
        if (b == 1 && state == false) {
            if (cx >= x && cx < x+w && cy >= y && cy < y+h) // button event
                Stdout ("Button clicked!").newline;
            
            pushed = false;
            mgr.requestRedraw;
            mgr.removeCallbacks (cast(void*) this);
            
            return true;
        }
        return false;
    }
    void motionWhileHeld (wdabs cx, wdabs cy) {
        bool oldPushed = pushed;
        if (cx >= x && cx < x+w && cy >= y && cy < y+h) pushed = true;
        else pushed = false;
        if (oldPushed != pushed)
            mgr.requestRedraw;
    }
}