module doodle.dia.tool_layer;

public {
    import doodle.dia.tool;
}

private {
    import std.stdio;
    import doodle.cairo.routines;
}

class ToolLayer : Layer, EventHandler {
    this(in Tool[] tools, in string name) {
        super(name);
        mTools = tools.dup;
    }

    // Layer overrides:

    override Rectangle bounds() const {
        return Rectangle();
    }

    override void draw(const Viewport viewport,
                       in Rectangle pixel_damage, scope Context pixel_cr,
                       in Rectangle model_damage, scope Context model_cr) const {
        // FIXME this isn't how we will really draw the tools...
        foreach (const Tool tool; mTools) {
            tool.draw(viewport, pixel_damage, pixel_cr, model_damage, model_cr);
        }
    }

    // EventHandler overrides:

    override bool handle_button_press(scope Viewport viewport, in ButtonEvent event) {
        // writefln("%s", event);

        if (mGrabbedTool is null) {
            foreach_reverse(ref tool; mTools) {
                if (tool.handle_button_press(viewport, event)) {
                    mGrabbedTool = &tool;
                    mGrabbedButton = event.button_name;
                    break;
                }
            }
        }
        else {
            mGrabbedTool.handle_button_press(viewport, event);
        }

        return true;
    }

    override bool handle_button_release(scope Viewport viewport, in ButtonEvent event) {
        // writefln("%s", event);

        if (mGrabbedTool !is null) {
            mGrabbedTool.handle_button_release(viewport, event);

            if (mGrabbedButton == event.button_name) {
                mGrabbedTool = null;
            }
        }

        return true;
    }

    override bool handle_key_press(scope Viewport viewport, in KeyEvent event) {
        // writefln("%s", event);

        return true;
    }

    override bool handle_key_release(scope Viewport viewport, in KeyEvent event) {
        // writefln("%s", event);

        return true;
    }

    override bool handle_motion(scope Viewport viewport, in MotionEvent event) {
        //writefln("%s", event);

        if (mGrabbedTool is null) {
            foreach_reverse(ref tool; mTools) {
                if (tool.handle_motion(viewport, event)) {
                    break;
                }
            }
        }
        else {
            mGrabbedTool.handle_motion(viewport, event);
        }

        return true;
    }

    override bool handle_scroll(scope Viewport viewport, in ScrollEvent event) {
        // writefln("%s", event);

        if (mGrabbedTool is null) {
            foreach_reverse(ref tool; mTools) {
                if (tool.handle_scroll(viewport, event)) {
                    break;
                }
            }
        }
        else {
            mGrabbedTool.handle_scroll(viewport, event);
        }

        return true;
    }

    /*
    override void push(Tool tool) {
    }

    override void pop() {
    }

    override void replace(Tool tool) {
    }
    */

    private {
        Tool[] mTools;
        Tool * mGrabbedTool;
        ButtonName mGrabbedButton;
    }
}