module dmd.CatAssignExp;

import dmd.common;
import dmd.BinExp;
import dmd.Loc;
import dmd.Expression;
import dmd.Scope;
import dmd.InterState;
import dmd.SliceExp;
import dmd.Identifier;
import dmd.IRState;
import dmd.TOK;
import dmd.TY;
import dmd.Id;
import dmd.Type;
import dmd.backend.elem;
import dmd.backend.RTLSYM;
import dmd.backend.Util;
import dmd.backend.OPER;
import dmd.backend.TYM;
import dmd.backend.mTY;

import dmd.expression.Cat;
import dmd.expression.Util;

class CatAssignExp : BinExp
{
    this(Loc loc, Expression e1, Expression e2)
	{
		super(loc, TOK.TOKcatass, CatAssignExp.sizeof, e1, e2);
	}
	
    override Expression semantic(Scope sc)
	{
		Expression e;

		BinExp.semantic(sc);
		e2 = resolveProperties(sc, e2);

		e = op_overload(sc);
		if (e)
			return e;

		if (e1.op == TOKslice)
		{	
			SliceExp se = cast(SliceExp)e1;

			if (se.e1.type.toBasetype().ty == Tsarray)
				error("cannot append to static array %s", se.e1.type.toChars());
		}

		e1 = e1.modifiableLvalue(sc, e1);

		Type tb1 = e1.type.toBasetype();
		Type tb2 = e2.type.toBasetype();

		e2.rvalue();

		if ((tb1.ty == Tarray) &&
			(tb2.ty == Tarray || tb2.ty == Tsarray) &&
			(e2.implicitConvTo(e1.type) ||
			tb2.nextOf().implicitConvTo(tb1.nextOf()))
		   )
		{	// Append array
			e2 = e2.castTo(sc, e1.type);
			type = e1.type;
			e = this;
		}
		else if ((tb1.ty == Tarray) &&
			e2.implicitConvTo(tb1.nextOf())
		   )
		{	// Append element
			e2 = e2.castTo(sc, tb1.nextOf());
			type = e1.type;
			e = this;
		}
		else
		{
			error("cannot append type %s to type %s", tb2.toChars(), tb1.toChars());
			type = Type.tint32;
			e = this;
		}
		return e;
	}
	
    override Expression interpret(InterState istate)
	{
    	return interpretAssignCommon(istate, &Cat);
	}

    override Identifier opId()    /* For operator overloading */
	{
		return Id.catass;
	}

    override elem* toElem(IRState* irs)
	{
		//printf("CatAssignExp.toElem('%s')\n", toChars());
		elem* e;
		Type tb1 = e1.type.toBasetype();
		Type tb2 = e2.type.toBasetype();

		if (tb1.ty == Tarray || tb2.ty == Tsarray)
		{   elem* e1;
			elem* e2;
			elem* ep;

			e1 = this.e1.toElem(irs);
			e1 = el_una(OPaddr, TYnptr, e1);

			e2 = this.e2.toElem(irs);
			if (tybasic(e2.Ety) == TYstruct || tybasic(e2.Ety) == TYarray)
			{
				e2 = el_una(OPstrpar, TYstruct, e2);
				e2.Enumbytes = e2.E1.Enumbytes;
				assert(e2.Enumbytes);
			}

			Type tb1n = tb1.nextOf().toBasetype();
			if ((tb2.ty == Tarray || tb2.ty == Tsarray) &&
				tb1n.equals(tb2.nextOf().toBasetype()))
			{   // Append array
		static if (true) {
				ep = el_params(e2, e1, this.e1.type.getTypeInfo(null).toElem(irs), null);
				e = el_bin(OPcall, TYdarray, el_var(rtlsym[RTLSYM_ARRAYAPPENDT]), ep);
		} else {
				ep = el_params(el_long(TYint, tb1n.size()), e2, e1, null);
				e = el_bin(OPcall, TYdarray, el_var(rtlsym[RTLSYM_ARRAYAPPEND]), ep);
		}
			}
			else
			{   // Append element
		static if (true) {
				ep = el_params(e2, e1, this.e1.type.getTypeInfo(null).toElem(irs), null);
				e = el_bin(OPcall, TYdarray, el_var(rtlsym[RTLSYM_ARRAYAPPENDCT]), ep);
		} else {
				ep = el_params(e2, el_long(TYint, tb1n.size()), e1, null);
				e = el_bin(OPcall, TYdarray, el_var(rtlsym[RTLSYM_ARRAYAPPENDC]), ep);
		}
			}
			el_setLoc(e,loc);
		}
		else
			assert(0);

		return e;
	}
}