/**
 * This file is part of the dcrypt project.
 *
 * Copyright: Copyright (C) dcrypt contributors 2008. All rights reserved.
 * License:   MIT
 * Authors:   Thomas Dixon
 */

module dcrypt.crypto.ciphers.TEA;

import dcrypt.misc.Util;
import dcrypt.crypto.BlockCipher;

/** Implementation of the TEA cipher designed by
    David Wheeler and Roger Needham. */
class TEA : BlockCipher {
    private {
        const uint ROUNDS = 32,
                   KEY_SIZE = 16,
                   BLOCK_SIZE = 8,
                   DELTA = 0x9e3779b9,
                   DECRYPT_SUM = 0xc6ef3720;
        uint sk0, sk1, sk2, sk3, sum;
        bool initialized,
             encrypt;
    }
    
    void reset(){}
    
    char[] name() {
        return "TEA";
    }
    
    uint blockSize() {
        return BLOCK_SIZE;
    }
    
    void init(bool encrypt, CipherParameters params) {
        SymmetricKey keyParams = cast(SymmetricKey)params;
        if (!keyParams)
            throw new InvalidParameterError(
                    name()~": Invalid parameter passed to init");
        this.encrypt = encrypt;
                    
        if (keyParams.key.length != KEY_SIZE)
            throw new InvalidKeyError(
                    name()~": Invalid key length (requires 16 bytes)");
        
        sk0 = Util.ubytesToUintBig(keyParams.key, 0);
        sk1 = Util.ubytesToUintBig(keyParams.key, 4);
        sk2 = Util.ubytesToUintBig(keyParams.key, 8);
        sk3 = Util.ubytesToUintBig(keyParams.key, 12);

        initialized = true;
    }
    
    ubyte[] process(void[] input_) {
        if (!initialized)
            throw new NotInitializedError(name()~": Cipher not initialized");
            
        ubyte[] input = cast(ubyte[]) input_;
                    
        if (input.length < blockSize)
            throw new ShortBufferError(name()~": Input buffer too short");
        
        uint v0 = Util.ubytesToUintBig(input, 0),
             v1 = Util.ubytesToUintBig(input, 4);
        
        sum = encrypt ? 0 : DECRYPT_SUM;
        for (int i = 0; i < ROUNDS; i++) {
            if (encrypt) {
                sum += DELTA;
                v0 += ((v1 << 4) + sk0) ^ (v1 + sum) ^ ((v1 >> 5) + sk1);
                v1 += ((v0 << 4) + sk2) ^ (v0 + sum) ^ ((v0 >> 5) + sk3);
            } else {
                v1 -= ((v0 << 4) + sk2) ^ (v0 + sum) ^ ((v0 >> 5) + sk3);
                v0 -= ((v1 << 4) + sk0) ^ (v1 + sum) ^ ((v1 >> 5) + sk1);
                sum -= DELTA;
            }
        }
        
        ubyte[] output = new ubyte[blockSize];
        Util.uintToUbytesBig(v0, output, 0);
        Util.uintToUbytesBig(v1, output, 4);
        
        return output;
    }
    
    /** Some TEA test vectors. */
    unittest {
        static const char[][] test_keys = [
            "00000000000000000000000000000000",
            "00000000000000000000000000000000",
            "0123456712345678234567893456789a",
            "0123456712345678234567893456789a"
        ];
             
        static const char[][] test_plaintexts = [
            "0000000000000000",
            "0102030405060708",
            "0000000000000000",
            "0102030405060708"
        ];
            
        static const char[][] test_ciphertexts = [
            "41ea3a0a94baa940",
            "6a2f9cf3fccf3c55",
            "34e943b0900f5dcb",
            "773dc179878a81c0"
        ];
            
        
        TEA t = new TEA();
        foreach (uint i, char[] test_key; test_keys) {
            ubyte[] buffer = new ubyte[t.blockSize];
            char[] result;
            SymmetricKey key = new SymmetricKey(Util.hexToUbytes(test_key));
            
            // Encryption
            t.init(true, key);
            buffer = t.process(Util.hexToUbytes(test_plaintexts[i]));
            result = Util.ubytesToHex(buffer);
            assert(result == test_ciphertexts[i],
                    t.name~": ("~result~") != ("~test_ciphertexts[i]~")");

            // Decryption
            t.init(false, key);
            buffer = t.process(Util.hexToUbytes(test_ciphertexts[i]));
            result = Util.ubytesToHex(buffer);
            assert(result == test_plaintexts[i],
                    t.name~": ("~result~") != ("~test_plaintexts[i]~")");
        }
    }
}